
Simulation Program for Integrated Circuits Emphasis
1)	Simulation program 	– how to approach simulation
- how to treat with simulation results
2)	Why MSIM Pspice (Orcad)
3)	Program development - text form of the circuit – schematics
4)	Program and file structure:
		The program in its original form contained 3 basic modules:
a) PSPICE	- Processes the input file in text form written by any text editor with the extension * .cir. The output file with * .out is a copy of the * .cir file extended by additional information. The file is extended with information from the simulation process, eventual error messages and tables of values at some points of circuit. The * .dat file is an extensive data file for the PROBE module
b) SCHEMATICS 	– Graphical schematic editor with output file *.cir (if we draw a circuit diagram, we do not have to write a text form (* .cir file) for the PSPICE module)
c) PROBE	- Graphical postprocessor, displays results in the form of graphs and allows mathematical operations, the input file is *. dat.
Note: for the latest versions of the PSPICE v9.x and 10.x, PROBE is part of PSPICE
5)	Netlist – part of a file *.cir

6)	Numeric constants:	- numbers are with a decimal point (NOT with comma!!!)
				-  whole numerical values (e.g., NOT 4k7, but 4.7k)
				- units abbreviation - femto, pico, nano, u – micro, milli, kilo, 
				   MEGa, Giga, Tera,
- It is not case sensitive, but it is recommended to use established designations for clarity.
[bookmark: _GoBack]			Attention!! - resistance 1M is 1miliohm,
7)	component library modules:
- the model of the component used for the calculation is in the   * .lib library and this library must be specified in the * .cir file
		File location: X:\Program Files\Orcad\Capture\Library\PSpice\
- the component model for the schematic editor is in the * .slb file
- components are divided in libraries into larger characteristic groups, and component types are then selected directly from the groups.
		File location: X:\Program Files\Orcad\PSpice\Library\
- libraries that are not loaded at startup must be linked to the program if we want to use components from these libraries: 
library *.lib – Analysis – Library a include files..
				library *.slb – Options – Editor configuration 

8) 	the most commonly used components and their location in libraries:
- different types of independent sources....................................................	source.slb
- different types of dependent sources.......................................................	abm.slb
- R,C,L, sources E,G,F,H ,
   variable resistor Rvar (only two-pin, NOT potentiometer) ………………  	analog.slb
- variable resistor Pot ( three-pin -  potentiometer),
non-linear transformers with core.............................................................         	breakout.slb
- three-phase transformers, normally open and normally closed switch,
 relay, 555, linear transformers................................................................	anl_misc.slb
- overseas bipolar transistors (mostly series 2Nxxxx) ............................	bipolar.slb 
- bipolar transistors darlington.................................................................	darlingtn.slb
- diodes 1Nxxxx, zener diodes 1Nxxx, MBRxxx, MUR, BYW..    	diode.slb
- European bipolar transistors BC, BF, BS ............................................       	ebipolar.slb
- European diodes BS, BAS, BAV, BAW, BAT ......................................  	ediode.slb 
- European power bipolar transistors BDX, BSS, BU ............................         	epwrbjt.slb
- Japanese low power bipolar transistors 2SA, 2SB, 2SC………………….	jbipolar.slb
- Japanese low power fet transistors BF, J, 2N ...................................…….   	 jfet.slb
- Japanese power fet transistors 2SJ ..................................................…….       	jjfet.slb
- Japanese power bipolar transistors 2SA, 2SB, 2SC, 2SD ...............…….       	jpwrbjt.slb
- Japanese diodes and zener diodes – at ZD is directly visible voltage......     	jdiode.slb
- Japanese power fet transistors 2SK .........................................................       	jpwrmos.slb
- common types of operational amplifiers...................................................       	opamp.slb
- common optocouplers..............................................................................         	opto.slb
- power bipolar transistors BD, BUV, BUX, MJE, TIP ................................         	pwrbjt.slb
- power MOSFET transistors IRF ..............................................................         	pwrmos.slb
- parameters, power supply interface.........................................................         	special. slb
- ferromagnetic cores..................................................................................          magnetic.slb
- thyristors and triacs...................................................................................          thyristr.slb














Transient analysis 

RC_integration

[image: ]
Example of * .cir file - this file can be opened directly in the pspice.exe program and run

** Analysis setup **
.tran 0ns 10ms
.OP 
.lib "nom.lib"
V_V1         $N_0001 0 10V
R_R1         $N_0001 $N_0002  1k  
C_C1         $N_0002 0  1u IC=0 

.PROBE V(*) 
.END
- show the effect of initial conditions at cap.






Transient analysis 

RC_int_sw

[image: ]
File generated by the schematic editor:

* Schematics Version 9.2
* Sun Feb 20 13:53:40 2005
** Analysis setup **
.tran 0ns 10ms
.OP 
.LIB "D:\Program Files\Orcad\PSpice\Moje_design\X.lib"
* From [PSPICE NETLIST] section of E:\Program Files\Orcad_92\PSpice\PSpice.ini:
.lib "nom.lib"
.INC "RC_int_sw.net"
**** INCLUDING RC_int_sw.net ****
* Schematics Netlist *
V_V1         $N_0001 0 10V
R_R1         $N_0003 $N_0002  1k  
C_C1         $N_0002 0  1u IC=0 
X_U2         $N_0001 $N_0003 Sw_tClose PARAMS: tClose=1ms ttran=1u Rclosed=0.01
+  Ropen=10Meg
**** RESUMING RC_int_sw.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 

.END




Examples of independent sources
	Vxxx	= voltage sources
	Ixxx	= current sources
[image: ]VDC
- DC power supply


[image: ]VSIN   (sample file 	V_SIN.sch, V_SIN_tlum )
.tran 1u 5ms
DC 0 SIN 0 5V 1k 0 0 0
- generates a voltage sine wave with amplitude 5V and f = 1kHz
-.tran 1u 5ms  - list of samples in PROBE within 5ms with 1us sample – show the effect of list of samples with 1ms sample.
Command 	-   SIN(VOFF VAMPL FREQ TD DF PHASE)
	VOFF	 – voltage offset
VAMPL– voltage amplitude
FREQ	 – frequency
TD 	 – source voltage start delay, at t <TD the source voltage is 0V, (if not PHASE)
DF	 – damping factor, (damping has an exponential character)
PHASE – initial phase in degrees

[image: ] VPULSE   (sample file         V_Pulse.sch, V_pulse_pila,Pulse_trig)
PULSE -2 2 0 1p 1p 2u 4u
- generates a rectangular waveform -2 / 2V, Duty cycle 1: 1, period 4us
          
Command	-    PULSE(V1 V2  Td Tr  Tf  Tw  Per)
[image: ]			



[image: ]VPWL  (sample file 	V_PWL.sch)
PWL 0 0 1u 10V 2u 5V 3u 7V 4u -2V 5u 0 6u -5V 7u -5V 8u 10V 9u 5V
- generates a one-time signal defined in ten points by time and voltage
The PWL source is a Piece Wise Linear function
Command -      point 2 point 3 point 4 … 
           PWL(1ms 12V 3ms 15V 8ms 4V …)
VPWL_ENH (sample file	V_PWL_enhance.sch)
		PWL  REPEAT FOR 5 2u,3V 4u, 5V 5u, -5V,  ENDREPEAT
- generates a voltage course defined at three points 5 times in a row
Command -      			  point 2 point 3 point 4 … 
           PWL REPEAT FOR 5 (1ms 12V 3ms 15V 8ms 4V …)
· FOR 5: 5 times ( FOR how many times)
VPWL_FILE (sample file 	V_PWL_FILE.sch)
		PWL    REPEAT FOR 3 FILE "prubeh.txt"  ENDREPEAT
		- generates the voltage profile specified in the file and repeats it by the 
  specified number.
Command -  			  	    File Name 
           PWL REPEAT FOR 5 FILE "prubeh.txt"  ENDREPEAT
· FOR 5: 5 times ( FOR how many times)
file format – text, in a common directory with the simulated file, 

e.g: 1u 1V 2u 3V 3u -5V 4u 0 5u 10 6u 8 7u 5 8u 5 8.1u 0 9u 0 10u 0 11u -5 12u -4 13u -6 14u -6 15u 0[image: ]
VEXP   (sample file 	V_EXP.sch )
EXP 0 10V 1u 2u 12u 2u
- generates a single pulse with exp. rise and exp. fall
Command -       
         EXP(V1    V2     TD1     TC1       TD2         TC2)
		voltage 1 voltage 2  delay   time exp. rise  time to peak      time exp. fall
[image: ] VSFFM  (sample file 	V_SSFM_FM.sch)

SFFM 0 2 10k 10 500
- generates a frequency modulated signal with a carrier frequency of 10kHz 
and a transmitted frequency of 500Hz and a modulation stroke of 5kHz.
Command -       
         VSFFM(VOFF  VAMPL  FC  MOD  FM)
		VOFF		= 	voltage offset of the signal
		VAMP	L	= 	signal amplitude
		FC		= 	carrier frequency
		MOD		=	modulation index = > MOD = FC / FM
FM 		=	transmitted modulation frequency



Examples of E type sources (dependent sources)

	E = voltage controlled voltage source
	G = voltage controlled current source
	F = current controlled current source
	H = current controlled voltage source



















1) Example of an amplifier with output offset, file Evalue_example.sch
E VALUE

[image: ]

** Analysis setup **
.tran 0ns 1000ns
.OP 
* From [PSPICE NETLIST] section of D:\Program Files\Orcad\PSpice\PSpice.ini:
.lib "nom.lib"
.INC "Evalue_priklad.net"
**** INCLUDING Evalue_priklad.net ****
* Schematics Netlist *

V_V1         $N_0001 0 1V
R_R1         $N_0002 0  1k  
E_E3         $N_0002 0 VALUE { V($N_0001, 0)*10+5 }

**** RESUMING Evalue_priklad.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 


.END


Output voltage is   (UIN  * 10 )      +      5       =     15V
			       multiplication	       offset
2) example – accurate full-wave rectifier, file E_rect.sch
E VALUE

[image: ]
Sine voltage source with amplitude 1 V and frequency 100 kHz

** Analysis setup **
.tran 10n 30us
.OP 

.lib "nom.lib"

R_R1         $N_0001 0  1k  
V_V2         $N_0002 0 DC 0 AC 0
+SIN 0 1 100k 0 0 0
E_E5         $N_0001 0 VALUE { ABS(V($N_0002, 0)) }

**** RESUMING E_rect.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 

.END


The result is a full-wave rectified output voltage.



3) example - accurate half-wave rectifier, file E_rect_half.sch
E VALUE

[image: ]
Sine voltage source with amplitude 1 V and frequency 100 kHz

** Analysis setup **
.tran 10n 30us
.OP 
.lib "nom.lib"
R_R1         $N_0001 0  1k  
V_V2         $N_0002 0 DC 0 AC 0
+SIN 0 1 100k 0 0 0
E_E5         $N_0001 0 VALUE { {V($N_0002, 0)*(EXP(10*V($N_0002,
+  0))/EXP(ABS(10*V($N_0002, 0))))} }

**** RESUMING E_rect_half.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 

.END

[bookmark: _Hlk84948913]A formula is used to describe a half-wave rectifier:

		
The result is a half-wave rectified output voltage.

4) example – voltage controlled oscillator VCO, file E_val_VCO.sch
E VALUE
[image: ]
.PARAM         K=25k 
.PARAM         twopi=6.283185 A=2 Fc=50k
** Analysis setup **
.tran 100ns 300u
.OP 
.lib "nom.lib"
R_R1         $N_0001 0  1k  
E_E5         $N_0001 0 VALUE { A*sin(twopi*TIME*(Fc+K*V($N_0002, 0))) }
V_V1         $N_0002 0 DC 0 AC 0
+PWL 0 1 100u 1 100.001u 0 200u 0 200.001u -1 300u -1 300.001u 0 
**** RESUMING E_val_VCO.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END
Description of voltage controlled oscillator behavior - basic equation:
		fOUT    =       fC     +              K    *             UIN
	output f	  mean f       sensitivity of VCO    control voltage
					    Hz/V
	UOUT =   A * sin  (twopi * TIME * (Fc + K * V($N_0002, 0)))
  amplitude	        2x 3.14	    Time - internal variable of Pspice
Result: control voltage 1V – 0V -  -1V
    f OUT =  75kHz – 50kHz – 25kHz

5) example – Summing amplifier, file E_val_sum.sch
E VALUE
[image: ]
** Analysis setup **
.tran 10n 30us
.OP 
.lib "nom.lib"
R_R1         $N_0001 0  1k  
V_V4         $N_0002 0 3V
E_E5         $N_0001 0 VALUE { V($N_0002, 0)+V($N_0003,0) }
V_V3         $N_0003 0 5V

**** RESUMING E_val_sum.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 

.END


The output voltage is 8V.
6) example – realization of nonlinearity by table, 				file - Etable_priklad.sch
E TABLE
[image: ]
** Analysis setup **
.tran 0ns 1000ns
.OP 
.lib "nom.lib"
V_V1         $N_0001 0 1V
R_R1         $N_0002 0  1k  
E_E4         $N_0002 0 TABLE { V($N_0001, 0)*3 } ( (1,16)(2,17)(3,30) )

**** RESUMING Etable_priklad.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END

Output:
if the result of the control expression is 2 - 3, the output will be 30V,
if the result of the control expression is 1 - 2, the output will be 17V,
if the result of the control expression is <1, the output will be 16V,







It can be better seen with variable input voltage 
- see file Etable_priklad_parametr.sch

.PARAM         UIN=1V 
.DC LIN PARAM UIN 0 1 0.01 
.OP 
.lib "nom.lib"
R_R1         $N_0001 0  1k  
E_E4         $N_0001 0 TABLE { V($N_0002, 0)*3 } ( (1,16)(2,17)(3,30) )
V_V1         $N_0002 0 {UIN}

**** RESUMING Etable_priklad_parametr.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END
7) example – comparator implementation, file Etable_komp.sch

E TABLE
[image: ]
** Analysis setup **
.tran 1us 3ms
.OP 
.lib "nom.lib"
R_R1         $N_0001 0  1k  
E_E4         $N_0001 0 TABLE { V($N_0002, $N_0003)*200000 } ( (0,-15)(0.01,15) )
V_V3         $N_0003 0 6V
V_V2         $N_0002 0 DC 0 AC 0 SIN 0 10 1k 0 0 0

**** RESUMING Etable_komp.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END

Description of circuit‘s behavior:
TABLE { V($N_0002, $N_0003)*200000 } ( (0,-15)(0.01,15) )
	
	comparator gain between inputs	definition of the threshold and output values

The result is a comparison of a sine voltage with an amplitude of 10 V and input frequency f = 1kHz + with a 6V input DC voltage.
8) example – filter implementation, file Efreq_lowpass.sch
E FREQ
[image: ]
** Analysis setup **
.ac DEC 100 0.01 10
.OP 
.lib "nom.lib"
R_R1         $N_0001 0  1k  
V_V4         $N_0002 0 DC 0V AC 1V 
E_E5         $N_0001 0 FREQ { V($N_0002, 0) } =    ( (0.1,0,-10)(0.5,-0.27,-44)(0.6,-0.53,
-54)(0.8,-1.5,-73)(1,-3,-90)(1.25,-5,-108)(2,-12,-137)(3,-19,-151)(4,-24,-160)) 

**** RESUMING Efreq_lowpass.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 

.END

Result:

phase and attenuation characteristics given by the table for
Second order Butterworth filter,
in the table is always in brackets:
(frequency, attenuation in dB, phase in degrees)

The simulation is runing for a frequency range from 0.01 Hz to 10Hz
9) example – implementation of the filter given by the operator function
E LAPLACE
[image: ]
.PARAM         Pi=3.1415926 A1={(2*Pi*omega*Fc)*(2*Pi*omega*Fc)} A2={(2*Pi*omega*Fc)/Q}
.PARAM         omega=0.841 Q=1.307 Fc=5k
** Analysis setup **
.ac DEC 500 1 50k
.OP 
.lib "nom.lib"
R_R1         $N_0001 0  1k  
V_V4         $N_0002 0 DC 0V AC 1V 
E_E7         $N_0001 0 LAPLACE { V($N_0002, 0) } = { A1/(s*s+A2*s+A1) }

**** RESUMING Elaplace_Lowpass.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 

.END

This is the implementation of the voltage transfer of the filter given by the Laplace function:

;   the filter is described by A1 and A2 parameters:


    ;     ;

Parameters Q for various types second-order low-pass filters:
·   		   Q
Butterworth		1		0,707		 = Normalized frequency rad/sec
Chebyshev (0,5dB)	1,231		0,864		Fc = cutoff frequency
Chebyshev (1dB)	1,05		0,957		Q = qualitative factor
Chebyshev (2dB)	0,907		1,129
Chebyshev (3dB)	0,841		1,307
Bessel			1,73		0,577

10) example – implementation of amplitude modulation, file E_multi_AM.sch
E MULTI
[image: ]
** Analysis setup **
.tran 0ns 200us
.OP 
.lib "nom.lib"
V_V1         $N_0001 0 DC 0 AC 0 SIN 0 1V 10k 0 0 0
V_V2         $N_0002 0 DC 0 AC 0 SIN 0 1V 500k 0 0 0
R_R1         0 $N_0003  1k  
E_E1         $N_0003 0 VALUE {V($N_0001,0)*V($N_0002,0)}

**** RESUMING E_multi_AM.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 


.END
The result is 100% amplitude modulation
f - carrier is 500kHz, f modulation is 10kHz,
The modulation depth is controlled by the VOFF (offset) parameter at the modulation frequency source
11) Example – Summing amplifier, file Esum_priklad.sch
E SUM
[image: ]

** Analysis setup **
.tran 0ns 1000ns
.OP 
* From [PSPICE NETLIST] section of D:\Program Files\Orcad\PSpice\PSpice.ini:
.lib "nom.lib"

.INC "Esum_priklad.net"

**** INCLUDING Esum_priklad.net ****
* Schematics Netlist *


V_V2         $N_0001 0 3V
V_V1         $N_0002 0 1V
E_E5         $N_0003 0 VALUE {V($N_0001,0)+V($N_0002,0)}
R_R1         $N_0003 0  1k  

**** RESUMING Esum_priklad.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 

.END
The output voltage is 4V.
[image: ]12) example –  AM modulation and demodulation, file AM_mod_dem.sch
.PARAM         omega=1 Q=0.707 Fc=1k
.PARAM         pi=3.1415926 A1={(2*Pi*omega*Fc)*(2*Pi*omega*Fc)} A2={(2*Pi*omega*Fc)/Q}
** Analysis setup **
.tran 0ns 4m
.OP 
.lib "nom.lib"
V_V4         $N_0001 0  
+SIN 0 1V 100k 0 0 0
E_E1         $N_0002 0 VALUE { V($N_0003, 0)+V($N_0004,0) }
V_V1         $N_0004 0 1V
E_E2         $N_0005 0 VALUE { V($N_0002,0)*V( $N_0001,0) }
E_E3         $N_0006 0 VALUE { {V($N_0005, 0)*(EXP(10*V($N_0005,
+  0))/EXP(ABS(10*V($N_0005, 0))))} }
R_R1         0 $N_0007  1k  
E_E4         $N_0008 0 LAPLACE { V($N_0006, 0) } = { A1/(s*s+A2*s+A1) }
E_E5         $N_0007 0 $N_0008 0 4
V_V2         $N_0003 0  
+SIN 0 0.5 1k 0 0 0
**** RESUMING AM_mod_dem.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END

Block description:
E1 = summation (fmod + depth mod), E2 = multiplier (f mod with offset * f carrier),
E3 = half-wave rectifier, E4 = Butterworth filter, E5 = 4x gain

Fourier analysis can be performed. You must enter the mean frequency, the number of harmonics, and the output variable V (E2: OUT +) in the Transient Analysis dialog box and check Enable Fourier.

AC analysis (AC Sweep),file CR.sch

[image: ]

** Analysis setup **
.ac DEC 10 10 1G
.OP 

* From [PSPICE NETLIST] section of D:\Program Files\Orcad\PSpice\PSpice.ini:
.lib "nom.lib"

C_C1         $N_0001 $N_0002  1n  
R_R1         0 $N_0002  1k  
V_V10         $N_0001 0 DC 0V AC 1V
**** RESUMING CR.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 

.END

Either VSRC or VAC source can be used for AC analysis.

For frequency characteristic:
The same result as the VDB marker gives the mathematical equation written in PROBE:
20*LOG10(V($N_0002)/ V($N_0001))
 !!!!!! Pay attention!!!! LOG (xxx) is natural logarithm, LOG10(xxx) is common logarithm


This is an equation:	   

For phase characteristic:
The mathematical equation written in PROBE gives the same result as the VP marker::
(ARCTAN((1/(2*pi*1000*0.000000001))/FREQUENCY)*180/ pi)



This is an equation:	 ;	;     

Conversion to degrees:     ; 
FREQUENCY = internal variable in calculation

Pay attention to MARKER VDB  !!!!!!



In the last case the result is the same as last time with when marker VDB was used in equation for voltage transfer in decibels: . They are equal only because the denominator in the fraction U1 is 1V, which we used as input voltage of the V4 source. If we instead choose 10V or 0.1V, we will get instead passband voltage values of high pass filter in levels of 20dB(-20dB). 


MARKER VDB only tells the voltage levels in decibels without any link to the actual voltage transfer!!!!


To show transfer in dB we must use given equation in PROBE, or use defined function in PROBE called DB(xxxx). Ratio of output and input variable is used in the bracket.  

For example, which can be find in file CR_VDB.sch it is: 

[image: Diagram

Description automatically generated]

Use in PROBE: choose Trace – Add Trace – in line Trace expression put:

DB(V(R1:2)/V(V4:+))   

or

20*LOG10(V($N_0002)/ V($N_0001))

These expressions are equal.
















AC analysis      (file Efreq_priklad.sch)
E FREQ		filters....

[image: ]


** Analysis setup **
.ac LIN 101 10 10K
.OP 


* From [PSPICE NETLIST] section of D:\Program Files\Orcad\PSpice\PSpice.ini:
.lib "D:\Program Files\Orcad\Capture\Library\PSpice\TI_ANALOG.LIB"
.lib "nom.lib"

V_V5         $N_0001 0  AC 1 
R_R1         $N_0002 0  1k  
E_E6         $N_0002 0 FREQ { V($N_0001, 0) } =    
(+  (0,0,0)(5k,0,0)(6k,-60,-90)(7k,-60,-90)(8k,0,0) ) 

**** RESUMING Efreq_priklad.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 


.END


The filter parameters are entered in the table: (frequency, attenuation in dB, phase in degrees)




AC analysis      (file Rez_LC_paral.sch)

- parallel resonant circuit, impedance characteristic plotting
[image: ]

** Analysis setup **
.ac DEC 100 100k 10Meg
.OP 

* From [PSPICE NETLIST] section of C:\Program Files\Orcad\PSpice\PSpice.ini:
.lib "nom.lib"

L_L1         $N_0001 $N_0002  10uH  
C_C1         $N_0003 $N_0002  10n  
V_V1         $N_0002 0 DC 0V AC 1V 
R_R4         0 $N_0003  0.1  
R_R3         0 $N_0001  0.2  

.PROBE V(*) I(*) W(*) D(*) NOISE(*) 

.END

The impedance characteristic of the parallel resonant circuit shows a steep local maximum impedance (for an ideal L and C the maximum is infinitely high). Location on the frequency axis when neglecting parasitic elements is given by Thomson's formula:


 , The impedances of the coil and capacitor are the same in resonance:



The impedance of the resonant circuit Z is calculated as the ratio of the source voltage and the current taken from the source: In PROBE V (V1: +) / I (V1).  Curve with a maximum at 501kHz with an impedance of 2.5kOhm is plotted.

AC analysis      (file Rez_LC_serial.sch)
- serial resonant circuit, impedance characteristic plotting
[image: ]
** Analysis setup **
.ac DEC 100 100k 10Meg
.OP 

* From [PSPICE NETLIST] section of C:\Program Files\Orcad\PSpice\PSpice.ini:
.lib "nom.lib"

V_V1         $N_0001 0 DC 0V AC 1V 
L_L1         $N_0002 $N_0001  10uH  
C_C1         $N_0003 $N_0002  10n  
R_R3         0 $N_0003  0.3  

.PROBE V(*) I(*) W(*) D(*) NOISE(*) 

.END
A similar case as the previous one, the minimum of the resonance curve is the loss resistance
  RZ = RL+RESR = 0,3R. At the resonant frequency, the resonant circuit has the same capacitance and inductance and behaves as a purely ohmic resistor.

The impedance of the resonant circuit Z is calculated as the ratio of the source voltage and the current taken from the source: In PROBE V (V1: +) / I (V1).  Curve with a minimum at 501kHz with an impedance of 0.3Ohm is plotted.


Transient analysis   ( file VAC.sch)

[image: ]


** Analysis setup **
.tran 0ns 2ms
.OP 

* From [PSPICE NETLIST] section of D:\Program Files\Orcad\PSpice\PSpice.ini:
.lib "nom.lib"

V_V3         $N_0001 0 DC 0 AC 0 SIN 0 1 1k 0 0 0
R_R1         0 $N_0001  1k  

**** RESUMING VAC.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 


.END



Transient analysis   (file integrace_RC.sch )

- Integration


[image: ]

** Analysis setup **
.tran 0ns 30ms
.OP 


* From [PSPICE NETLIST] section of D:\Program Files\Orcad\PSpice\PSpice.ini:
.lib "D:\Program Files\Orcad\Capture\Library\PSpice\TI_ANALOG.LIB"
.lib "nom.lib"

R_R3         $N_0002 $N_0001  1k  
C_C2         0 $N_0001  1u  
R_R2         0 $N_0001  100k  
V_V2         $N_0002 0 DC 0 AC 0
+PWL 0 10 10m 10 10.0001m 0 12m 0 12.0001m -5 15m -5 15.0001m +10 20m +10
+  20.0001m 5 24m 5

**** RESUMING integrace_RC.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 


.END


Transient analysis   (file derivace_RC.sch)

- Derivation

[image: ]


** Analysis setup **
.tran 0ns 30ms
.OP 

* From [PSPICE NETLIST] section of D:\Program Files\Orcad\PSpice\PSpice.ini:
.lib "D:\Program Files\Orcad\Capture\Library\PSpice\TI_ANALOG.LIB"
.lib "nom.lib"

R_R2         0 $N_0001  100k  
V_V2         $N_0002 0 DC 0 AC 0
+PWL 0 10 10m 10 10.0001m 0 12m 0 12.0001m -5 15m -5 15.0001m +10 20m +10
+  20.0001m 5 24m 5
R_R4         0 $N_0001  1k  
C_C3         $N_0002 $N_0001  1u  

**** RESUMING derivace_RC.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 


.END



DC analysis   (file VDC.sch)


[image: ]



** Analysis setup **
.DC LIN V_V2 0 10 0.1 
.OP 

* From [PSPICE NETLIST] section of D:\Program Files\Orcad\PSpice\PSpice.ini:
.lib "nom.lib"

R_R1         0 $N_0001  1k  
V_V2         $N_0001 0   

**** RESUMING VDC.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 


.END



The result is a linear dependence of the voltage on the resistor and the current through the resistor.




Parametric analysis with transient analysis
									File: V_ANDC.sch

[image: ]
.PARAM         RZ=10 

** Analysis setup **
.tran 0ns 2ms
.STEP LIN PARAM RZ 10 100 10 
.OP 

* From [PSPICE NETLIST] section of D:\Program Files\Orcad\PSpice\PSpice.ini:
.lib "D:\Program Files\Orcad\Capture\Library\PSpice\TI_ANALOG.LIB"
.lib "nom.lib"


V_V4         $N_0001 0 10V
R_R1         0 $N_0001  {RZ}  

**** RESUMING V_ANDC.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 


.END


The result is 10 characteristics which are calculated in a given time range of the transient analysis with ten different values of the resistor R1.
DC analysis   
- parameter is variable resistor
						File:  Param_an.sch
[image: ]

.PARAM         RZ=10 

** Analysis setup **
.DC LIN PARAM RZ 10 100 0.01 
.OP 


* From [PSPICE NETLIST] section of D:\Program Files\Orcad\PSpice\PSpice.ini:
.lib "D:\Program Files\Orcad\Capture\Library\PSpice\TI_ANALOG.LIB"
.lib "nom.lib"


V_V4         $N_0001 0 10V
R_R1         0 $N_0001  {RZ}  

**** RESUMING Param_an.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 


.END

The result is one nonlinear characteristic with the dependence of the resistor current on its value.
DC analysis   
- parameter is adjustable potentiometer											File:  Set_potenciometer.sch
[image: ]

[image: ]

In the POT (potentiometer) component dialog, the parameter SET = xx. By default, after insertion into the circuit, the SET value is set to 0.5 and the value (VALUE) of the resistor is 1k. If we write our chosen parameter name in curly braces instead of 0.5 and define it in the PARAMETERS block, then we must enter this name (without parentheses) as a global parameter during setting up the simulation. Then we determine the start and end value, including the step of changing the parameter (increment).







.PARAM         SETTING=0.5 
** Analysis setup **
.DC LIN PARAM SETTING 0 1 0.001 
.OP 
.lib "nom.lib"
R_R4         0 $N_0001  1k  
R_R5         0 $N_0002  10Meg  
R_R2         $N_0004 $N_0003  1k  
V_V1         $N_0003 0 10V
X_R1    $N_0004 $N_0001 $N_0002 Set_potenciometer_R1 

.subckt Set_potenciometer_R1 1 2 t  
RT_R1         1 t {(1K*(1-{ SETTING }))+.001}
RB_R1         t 2 {(1K*{ SETTING })+.001}
.ends Set_potenciometer_R1

**** RESUMING Set_potenciometer.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END

The result of the DC analysis is a linearly changing voltage on the potentiometer slider from 3.333V to 6.666V depending on the change of the SETTINGS parameter.




















Parametric analysis    - application example - file:  DC_LR.sch

[bookmark: _Hlk85228226]The characteristics of current in a series LR circuit connected to a constant voltage source by a switch at time t.
[image: ]
* Schematics Version 9.2
.PARAM         RESR=10 
** Analysis setup **
.tran 0ns 120us
.STEP LIN PARAM RESR 0.001 105 10 
.OP 
* From [PSPICE NETLIST] section of E:\Program Files\Orcad_92\PSpice\PSpice.ini:
.lib "nom.lib"

V_V4         $N_0001 0 10V
X_U1         $N_0001 $N_0002 Sw_tClose PARAMS: tClose=0 ttran=1u Rclosed=0.0001
+  Ropen=100Meg
R_R1         $N_0003 $N_0002  {RESR}  
L_L1         $N_0003 0  1mH  

**** RESUMING DC_LR.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END

In this case, the circuit current in the transient will be calculated ten times, each time with a different value of resistance R1 (from 0.001 to 100R). The effect of the value of resistor R1 on the time constant  of the passing current can be seen here.


In the case of an almost ideal state, the solution of the circuit (RESR = 0) is simplified to the solution of the integral equation:	  - this is the equation of a straight line and it is valid only under ideal conditions!!!!!

In real conditions, RESR is not zero (RESR ≠ 0) and then the solution leads to a first-order differential equation:



 

 the current in the circuit is the sum of the ordinary and partial solution:

         =       partial solution = steady state solution!!!!

Ordinary solution:


; we are looking for an ordinary solution in the form 



 ;  ;    time constant 



 ;       for t = 0



   ; 		



The final solution of the current characteristic in the series circuit LR is:


               pro       

DC analysis   - two parameters
Temperature characteristics of the diode – file DC_dioda_TEMP
[image: ]
** Analysis setup **
.DC LIN V_V1 0.5 1 0.01 
+ LIN TEMP 0 100 10 
.OP 

.lib "nom.lib"

D_D1         $N_0001 0 D1N4007 
V_V1         $N_0001 0 DC 0.5
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END

The result is ten curves showing the VA characteristic of the diode at temperature changes from 0 ° C to 100 ° C for forward voltages from 0.5V to 1V

The main parameter is the voltage change of the V1 source from 0.5V to 1V, the nested second parameter is the temperature from 0 ° C to 100 ° C

The main parameter is entered in the DC analysis dialog in DC Sweep as a voltage source variable V1 with linear division. Nested parameter in the Nested Sweep dialog as a temperature variable with linear division.

Pay Attention! In the Nested Sweep dialog, calculation with a nested parameter must be enabled!
DC analysis – thermal analysis 

Change in the setting of the operating point (Q-point) of a transistor amplifier with a common emitter without temperature stabilization due to a changing temperature in the range from -20 ° C to 120 ° C  
 file:    T_zesil_sch
[image: ]
* Schematics Version 9.2
** Analysis setup **
.DC LIN TEMP -20 120 1 
.OP 
* From [PSPICE NETLIST] section of E:\Program Files\Orcad_92\PSpice\PSpice.ini:
.lib "nom.lib"
Q_Q1         $N_0002 $N_0001 0 Q2N2222
V_V1         $N_0003 0 12V
R_R1         $N_0002 $N_0003  10k  
R_R2         $N_0001 $N_0003  100k  
R_R3         0 $N_0001  5.75k  

**** RESUMING T_zesil.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END	steep

The result is a change in operating point due to changing temperature in the specified range. In the result can be seen that at -20 ° C the transistor is almost closed, at temperatures around 50 ° C is transistor open almost completely and the output voltage is zero. This is due to a circuit that does not have negative feedback in the emitter of the transistor. DC voltage ranges from 0V to 12V with a relatively steep waveform In the collector of the transistor. By default, if we do not change the temperature parameters, each calculation in the PSPICE program is solved for a temperature 27 ° C. For this temperature, the operating point of the above amplifier is also set to the center of the supply voltage, ie 6V.
The gain of the amplifier is about 160 times.
DC analysis – thermal analysis 2
Change in the setting of the operating point (Q-point) of a transistor amplifier with a common emitter with temperature stabilization (negative feedback) due to a changing temperature in the range from -20 ° C to 120 ° C  
file:    T_zesil_stab.sch
[image: ]
* Schematics Version 9.2
** Analysis setup **
.DC LIN TEMP -20 120 1 
.OP 
* From [PSPICE NETLIST] section of E:\Program Files\Orcad_92\PSpice\PSpice.ini:
.lib "nom.lib"
V_V1         $N_0001 0 12V
R_R1         $N_0002 $N_0001  10k  
R_R2         $N_0003 $N_0001  100k  
Q_Q1         $N_0002 $N_0003 $N_0004 Q2N2222
R_R4         0 $N_0004  2k  
R_R3         0 $N_0003  18.8k  

**** RESUMING T_zesil_stab.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END

In the circuit of an amplifier with a common emitter with negative current feedback, the temperature change in the range of -20 ° C to 120 ° C is reflected at the output of the amplifier in the collector of the transistor by a shift of the DC voltage in the range from 5V to 6.5V.
Amplifier gain is 5x.
DC analysis 
- Plotting VA characteristics of components

DIODE 			DC_Dioda.sch
			

 [image: ]

** Analysis setup **
.DC LIN V_V1 0.5 1 0.01 
.OP 
.lib "nom.lib"
V_V1         $N_0001 0 DC 1  
D_D1         $N_0001 0 D1N4007 

**** RESUMING DC_dioda.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END



Bipolar transistor		DC_Tranzistor.sch

[image: ]
[image: ]


















[image: ]** Analysis setup **
.DC LIN V_V1 0 10 0.1 LIN I_I1 1m 100m 5m 
.OP 
.lib "nom.lib"
I_I1         0 $N_0001   
V_V1         $N_0002 0   
Q_Q1         $N_0002 $N_0001 0 TIP41B

**** RESUMING DC_Tranzistor.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END





The output characteristics of the transistor TIP41B are plotted with this setting  (20 curves). Base current is set from 1mA to 100mA in 5mA steps in the DC Nested Sweep dialog. The input of voltage source V1 is calculated in each step in the main loop.

It is sufficient to control only the main loop to display the current conversion characteristic (beta), where the base current I1 changes and the voltage V1 is fixed.[image: ]


** Analysis setup **
.DC LIN I_I1 1m 100m 5m 
.OP 
.lib "nom.lib"
I_I1         0 $N_0001   
Q_Q1         $N_0002 $N_0001 0 TIP41B
V_V1         $N_0002 0 DC 10V  

**** RESUMING DC_Tranzistor.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 
.END

The input characteristic can be plotted by replacing the current source I1 with a voltage source and moving the current MARKER on the base of a transistor. We get the input characteristic of the transistor, which is the characteristic of the base diode.
MOSFET		DC_Mosfet.sch
[image: ]



[image: ]










[image: ]
** Analysis setup **
.DC LIN V_V1 0 10 0.1 
+ LIN V_V2 3 5 0.05 
.OP 
.lib "nom.lib"
V_V1         $N_0001 0   
M_M1         $N_0001 $N_0002 0 0 IRF044
V_V2         $N_0002 0   

**** RESUMING DC_Mosfet.cir ****
.PROBE V(*) I(*) W(*) D(*) NOISE(*) 

.END




The above DC analysis setting plots the output characteristics of the power MOSFET transistor.

It is only necessary to set the main loop to display the "Slope" parameter, where the voltage is set e.g. from 0 to 15V and the voltage of the V1 source is constant e.g. 10V.


AC Analysis     Oz_VdB.sch

- frequency characteristics OZ and stability

[image: ]

The MARKERS used in the diagram are Vreal and Vimanigary, which show in this analysis the magnitudes of the real and imaginary components of the output voltage depending on the frequency from 1mHz to 1GHz.


The frequency and phase characteristics can be displayed at the same time by selecting in PROBE - Trace - Add Trace - and enter the following in the Trace expression line:
Bode Plot dB - dual Y axes (V (R3: 2)), which can be found in the Functions or Macros - Plot Windows Templates window: (the output variable is enclosed in free brackets)
[image: ]

To plot the Nyquist stability criterion, you can enter: At PROBE - Trace - Add Trace - and enter the following command in the Trace expression line: Nyquist Plot (V (R3: 2)), which can be found in the Functions or Macros - Plot Windows Templates: (the output variable is written in free brackets)
















AC Analysis     		File   Wien_Oz_VdB.sch

- examination of the oscillator behavior with the Wien bridge oscillator

[image: ]

In transient analysis (TRANSIENT) is oscillator frequency set to 25kHz.

For stability analysis feedback is disconnected and VAC source is connected to input.


[image: ]
Frequency and phase characteristic can be shown together by choosing in PROBE - Trace – Add Trace – and input Bode Plot dB - dual Y axes(V(R11:2)), which can be fin in window Functions or Macros – Plot windows Templates into Trace expression. (Output variable is put into free brackets)

Nyquist’s stability criterium can be charted by choosing (in PROBE)- Trace -Add Trace – and put Nyquist Plot(V(R11:2)), which can be fin in window Functions or Macros – Plot windows Templates into Trace expression. (Output variable is put into free brackets)


Examples of using transformers

File - Trafo_2sec.sch

[image: ]

An example of using transformer XFRM_LIN

















File - Trafo_3sec.sch

[image: ]

An example of the implementation of a transformer built of separate inductors. The transformer coupling is determined by the K_Linear block.

Examples of simple regulators

- Rectifier – filter – Series regulator with Zener diode
File - USM_Z_DIODA.sch

[image: ]
- Parametric regulator – regulation with ZD – characteristics of ZD 
File - Z_DIODA.sch

[image: ]

- DC analysis with the dependence of the output voltage on the load resistance rz.

To display the classic load characteristic - the dependence of the output voltage on the output current can be plotted in PROBE by setting - Plot - Axis Setting - X axis - Axis Variable –Trace Expression write -I (R2)

V-A characteristic of the Zener diode

File - Char_ZD.sch

[image: ]



- Serial regulator without feedback

Linear1.sch

[image: ]


- - Serial regulator with feedback
File - Linear4.sch 

[image: ]

- plot VA load characteristic FoldBack
- draw attention to DC analysis - "battery powered"
- show the possibility of calculating the power on the load (-I(R3)* V(R3:2)), or W(R3), W(R5), W(Q1)

- The same stabilizer with standard current limitation
File - Linear4._Ilimsch
- show the difference between the power load of transistor Q1 !!![image: ]

- Serial regulator with IC LM723 		
file - Lin_stab2.sch
- show the difference in the power load of the output current sensing resistor R22.
This is another current protection circuit used to reduce the power loss of the sensing resistor[image: ]

[image: ]

- Switching regulators		
File - Imp_Zdroj.sch

- show the effect of capacitor C9 size on the switching frequency and also on the ripple of the output voltage[image: ]


- Example of three-phase rectifier simulation + FFT		
File - 3Fusm.sch

[image: ]
























-Example of magnetic material’s B-H curve	file - B_Hkrivka.sch

[image: Diagram

Description automatically generated]

-Different current charts for the currents I1, I2 and I3 can be seen. Different charts have different delay of current amplitude change by one period. 

For B-H curve:
B chart can be seen by inputting Trace – Add Trace – trace Expression B(K4) into Probe
Then in the settings – Plot – Axis Setting – X axis – Axis Variable – Trace Expression write -H(K4) – Attention – Computed values are B (Mag. induction) in Gauss and H (intensity of mag. field in Oersted).

B- 1 Tesla(T) = 10 000 Gauss(G)
H – 1 A/m = = 0,012566 Oersted (1 Oersted = 79,5775 A/m)

- Current source usage			
File - Zdroj_proudu.sch;

[image: A picture containing text, clock

Description automatically generated]
If we use almost ideal conditions (RESR=0), circuit equation can be simplified to an integral equation:


-Equation of line function and functions only for ideal conditions!!!!!

Resistor R2 is needed for the simulation, without it program would end with error because node would be floating!!!!

Example of using current power supply

File - Pila.sch

Real sawtooth generator 







[image: ]







- Example of an AC power regulator		
Files - Triac.sch; Triac_DC.sch

[image: ]


Triac.sch - simulation with constant power on load

Triac_DC.sch - simulation with a gradual increase in power on the load

- Demonstration of multivibrator function	

[image: ]
	
File - Multivibrator.sch

Pay attention to the initial conditions!!!


Flip-flop type D
File - Digital_D1.sch

[image: ]



File - Digital_D.sch

[image: ]

In this case, it is necessary to set the initial conditions of asynchronous inputs to 0 or 1 in Digital Setup. By default, they are set to an indefinite level.

File - Digital_analog_D.sch

[image: ]






Change of supply voltage for logic circuits 

-There are several methods of supply voltage realization in digital systems.

-In common simulated circuits we do not need to care about supplying voltage to digital circuits
-5V is common for TTL and CMOS integrated circuits

								file:   Napajeni_D.sch


In this example supply voltage of circuit CD4013 is changed to 18V


[image: Diagram

Description automatically generated]

Supply voltage is in dialog window marked as- positive pole ipin(VDD)=”name”
						        negative pole ipin(VSS)=”name”
-Formerly marked pole iping(VSS)=$G_CD4000_VSS is connected with node “0”
-New name “name” is for positive voltage and must be included in circuit!!!
[image: ]

Supply voltage realization by supply INTERFACE

		 file: Digital. sch

- In the next example every circuit has different supply voltage U1A=12V, U2A=6V, U3A=18V

-For U1A is voltage source defined by block PARAMETERS and if we add any other CMOS circuit, this supply voltage will be used – Global voltage level change

-For U2A and U3A is voltage defined by a supply voltage interface CD4000_PWR, where names of positive and negative supply voltage circuit U2A(U3A) and voltage is defined by VOLTAGE = XX

[image: ]

[image: ]







































Implementation of power supply of floating circuits

File- DIGITAL1.sch

[image: ]





- ABM conversion blocks



[image: ]


E.g.Usage for impulse driver signals with multiple floating levels




BandGap reference
- file Bandgap.sch

- reference circuit, DC analysis, parameter - temperature

[image: ]













 Creating subcircuits in PSpice
Definition of subcircuit: 
.SUBCKT <subcircuit_name> [local_nodes] [PARAMS: <<name> = <value>> ] 
...... 
......netlist of subcircuit
...... 
.ENDS 
[bookmark: _Hlk85312347]Calling a subcircuit: 
X<name> [global_nodes] < subcircuit_name > [PARAMS: <<name> = <value>>] 
- if PARAMS are not listed here, then the values from the definition of subcircuit are considered.
Example: 
OZ NE5532 - Definition of subcircuit downloaded from the web:
***** NE5532 Source: Texas Instruments NE5534 
* C2 added to simulate compensated frequency response (Uwe Beis) 
* NE5532 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT 
* CREATED USING NE5534 model from Texas InstrumentsAT 12:41 
* (REV N/A) SUPPLY VOLTAGE: +/-15V 
* CONNECTIONS: NON-INVERTING INPUT 
* | INVERTING INPUT 
* | | POSITIVE POWER SUPPLY 
* | | | NEGATIVE POWER SUPPLY 
* | | | | OUTPUT 
* | | | | | 
.SUBCKT NE5532 1 2 3 4 5 
*
…
… NETLIST 
… 
.ENDS 
Calling a subcircuit: 
X1 1 2 3 4 5 NE5532
Example: 
Transmission line element 
[image: ]
**** transmission line element with parameters**** 
.subckt transm_line_element in out gnd params: inductance=10u capacity=3p resistance=100k 
Ls in out {inductance} 
Cp out gnd {capacity} 
Rp out gnd {resistance} 
.ends 

Calling a subcircuit in a text input file:

Xline1 2 3 0 transm_line_element params: Ls=10u Cp=3p Rp=100k 
…
.subckt transm_line_element in out gnd params: inductance=10u capacity=3p resistance=100k 
Ls in out {inductance} 
Cp out gnd {capacity} 
Rp out gnd {resistance} 
.ends 
…
.END 



Possibility of drawing circuit diagram in Schematics - not possible with parameters ..[image: ]
Input / output terminals - IF_IN / IF_OUT. Next in Tools - Create Subcircuit - a subcircuit with the .sub extension is saved in the .sch directory. Then this file can be imported in the PSpice Model Editor.





Whole code for NE5532 IC

NE5532: 
***** NE5532 Source: Texas Instruments NE5534 
* C2 added to simulate compensated frequency response (Uwe Beis) 
* NE5532 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT 
* CREATED USING NE5534 model from Texas InstrumentsAT 12:41 
* (REV N/A) SUPPLY VOLTAGE: +/-15V 
* CONNECTIONS: NON-INVERTING INPUT 
* | INVERTING INPUT 
* | | POSITIVE POWER SUPPLY 
* | | | NEGATIVE POWER SUPPLY 
* | | | | OUTPUT 
* | | | | | 
.SUBCKT NE5532 1 2 3 4 5 
* 
C1 11 12 7.703E-12 
C2 6 7 23.500E-12 
DC 5 53 DX 
DE 54 5 DX 
DLP 90 91 DX 
DLN 92 90 DX 
DP 4 3 DX 
EGND 99 0 POLY(2) (3,0) (4,0) 0 .5 .5 
FB 7 99 POLY(5) VB VC VE VLP VLN 0 2.893E6 -3E6 3E6 3E6 -3E6 
GA 6 0 11 12 1.382E-3 
GCM 0 6 10 99 13.82E-9 
IEE 10 4 DC 133.0E-6 
HLIM 90 0 VLIM 1K 
Q1 11 2 13 QX 
Q2 12 1 14 QX 
R2 6 9 100.0E3 
RC1 3 11 723.3 
RC2 3 12 723.3 
RE1 13 10 329 
RE2 14 10 329 
REE 10 99 1.504E6 
RO1 8 5 50 
RO2 7 99 25 
RP 3 4 7.757E3 
VB 9 0 DC 0 
VC 3 53 DC 2.700 
VE 54 4 DC 2.700 
VLIM 7 8 DC 0 
VLP 91 0 DC 38 
VLN 0 92 DC 38 
.MODEL DX D(IS=800.0E-18) 
.MODEL QX NPN(IS=800.0E-18 BF=132) 
.ENDS
ESF II project of the University of West Bohemia in Pilsen, reg. number: CZ.02.2.69/0.0/0.0/18_056/0013239

